第三部分 高级语言特性

第14章 泛型

​ Object Pascal 提供的强类型检查对于提高代码的正确性非常有用，这也是我在本书中经常强调的一个主题。不过，强类型检查也可能带来麻烦，因为你可能想编写一个存储过程或类，对不同的数据类型进行类似的处理。对象 Pascal 语言的一个特性可以解决这个问题，类似的语言（如 C# 和 Java）也有这个特性，即泛型。

​ 泛型或模板类的概念实际上来自 C++ 语言。这是我 1994 年在一本关于 C++ 的书中所写的内容：你可以声明一个类，但不指定一个或多个数据成员的类型：这一操作可以推迟到该类的一个对象被实际声明时再进行。同样，您也可以在定义函数时不指定一个或多个参数的类型，直到函数被调用时为止。

注解 本文摘自我在 90 年代初与 Steve Tendon 合著的《Borland C++ 4.0 面向对象编程》一书。

​ 本章深入探讨了这一主题，从基础开始，也涵盖了一些高级使用场景，甚至说明了泛型如何应用于标准的可视化编程。

14.1 泛型键值对

​ 作为泛型类的第一个示例，我实现了一个键值对数据结构。以下是以传统方式编写的数据结构，使用对象来保存值：

type
  TKeyValue = class
  private
    FKey: string;
    FValue: TObject;
    procedure SetKey(const Value: string);
    procedure SetValue(const Value: TObject);
  public
    property Key: string read FKey write SetKey;
    property Value: TObject read FValue write SetValue;
  end;

​ 你可以使用这个类创建一个对象，设置它的键和值，如以下 KeyValueClassic示例主窗体的各种方法的代码段：

// FormCreate
Kv := TKeyValue.Create;

// Button1Click
Kv.Key := 'mykey';
Kv.Value := Sender;

// Button2Click
Kv.Value := Self; // 窗体

// Button3Click
ShowMessage('[' + Kv.Key + ',' + Kv.Value.ClassName + ']');

​ 如果需要一个类似的类来保存整数而不是对象，该怎么办呢？那么，要么进行非常不自然（而且危险）的类型转换，要么创建一个新的单独的类来保存带有数字值的字符串键。虽然复制并粘贴原来的类创建一个新类是一种解决方案，但你最终会得到两份基本相同的代码副本，这有悖于良好的编程原则，而且还需要进行噩梦般的维护，因为你必须为每个副本更新新功能，或修复两份、三份或二十份几乎完全相同的副本中的相同错误。

​ 泛型可以定义更宽泛的值，编写一个泛型类。一旦你实例化了键值泛型类，它就会变成一个特定的类，与给定的数据类型绑定。因此，你的应用程序中最终仍会编译两个、三个或二十个类，但所有这些类都有一个单一的源代码定义，它进行原生类型到类类型的类型检查，而且没有额外的运行时开销。

​ 但我说得太快了。让我们从定义键值对的通用类的语法开始：

type
  TKeyValue<T> = class
  private
    FKey: string;
    FValue: T;
    procedure SetKey(const Value: string);
    procedure SetValue(const Value: T);
  public
    property Key: string read FKey write SetKey;
    property Value: T read FValue write SetValue;
  end;

​ 在这个类的定义中，有一个未指定的类型，用放在尖括号中的占位符 T 表示。按照惯例，符号 T 常用来表示未指定的类型，但就编译器而言，你可以使用任何你喜欢的符号。当类只使用一个参数类型时，使用 T 通常会使代码更易读；如果类需要多个参数类型，通常会根据它们的实际作用来命名，而不是像 C++ 早期那样使用字母序列（T、U、V）。

注解 自 20 世纪 90 年代初 C++ 语言引入模板以来，"T "一直是泛型的标准名称或占位符。根据作者的不同，"T "代表 "类型 "或 “模板类型”。这一约定在 Delphi 世界中也被采用，因为类型一般都以 T 作为前缀，所以使用 "T "表示 "类型 "是合理的。

​ 泛型类TKeyValue<T>将未指定的类型用作其两个字段的类型，即属性值和setter方法的参数。方法按照通常的方式定义，但请注意，尽管它们与泛型类型有关，但它们的定义包含了完整的类名称，包括泛型类型：

procedure TKeyValue<T>.SetKey(const Value: string);
begin
  FKey := Value;
end;

procedure TKeyValue<T>.SetValue(const Value: T);
begin
  FValue := Value;
end;

​ 要使用该类，你必须完全限定它，提供泛型类型的实际类型。例如，现在你可以声明一个键值对象，其中的按钮作为值：

var
  Kv: TKeyValue<TButton>;

​ 在创建实例时，还需要提供完整的类型名称，因为这是实际的类型名称（而泛型、未实例化的类型名称就像一种类型构造机制）。

​ 对键-值对中的值指定一个特定类型会使代码更加健壮，因为现在你只能向键值对添加TButton（或派生的）对象，然后可以访问提取对象的各种方法和属性。以下是KeyValueGeneric示例主窗体的一些片段：

// FormCreate
Kv := TKeyValue<TButton>.Create;

// Button1Click
Kv.Key := 'mykey';
Kv.Value := Sender as TButton;

// Button2Click
Kv.Value := Sender as TButton; // 以前是“Self”，但那现在是无效的！

// Button3Click
ShowMessage('[' + Kv.Key + ',' + Kv.Value.Name + ']');

​ 在前一版本的代码中我们给泛型对象赋值时，我们可以添加按钮或窗体，现在我们只能添加按钮，这是编译器强制执行的规则。同样，在输出中，我们可以使用组件名字或 TButton 类的任何其他属性，而不是通用的 Kv.Value.ClassName。

​ 当然，我们也可以模仿原始程序，使用对象类型声明键值对，如：

var
  Kvo: TKeyValue<TObject>;

​ 在这个版本的泛型键-值对类中，我们可以添加任何对象作为值。但是，我们无法对提取出来的对象进行更多的操作，除非我们将它们转换为更具体的类型。为了找到一个很好的平衡点，你可能想在具体按钮和任意对象之间寻找一个平衡点，要求值是一个组件：

var
  Kvc: TKeyValue<TComponent>;

​ 你可以在相同的 KeyValueGeneric 示例中看到相应的代码片段。最后，我们还可以创建一个泛型键-值对类的实例，它不存储对象值，而是存储普通整数：

var
  Kvi: TKeyValue<Integer>;
begin
  Kvi := TKeyValue<Integer>.Create;
  try
    Kvi.Key := 'Object';
    Kvi.Value := 100;
    Kvi.Value := Left;
    ShowMessage('[' + Kvi.Key + ',' + IntToStr(Kvi.Value) + ']');
  finally
    Kvi.Free;
  end;